Hello.
I installed LiberKey on my system, on C:\LiberKey.
But i don't want to start LiberKey own menu each time i need to use an application.
So I am always creating in my Windows Start Menu manual links to the LiberKey\Apps\<applications>\*.exe files: in this way, i can use the nice Win7 Start Menu SEARCH functionality to start LiberKey Apps very quickly.

I think it would be a great thing to make a small tool, which should create all the links to all the LiberKey Apps found in the C:\LiberKey\Apps folders.
The links should be created inside a \LiberKey\ folder inside the Windows Start Menu.

Is there anything like this already available?
Thankyou.

Try this simple solution:
search *LKL.exe files, then drag & drop (+ Control + Shift) all founded files into Start Menu, it will create shortcuts.

Well, if you are a kind of superuser you can use following files to create a batch, a script or a small app to perform an automatic operation for it (correct me if I'm wrong in some point):

\LiberKey\LiberKeyTools\LiberKeyMenu\data\localapps.db.xml
- it lists all current apps installed in your LiberKey with details of each one
- use it to create the shortcut, using the app names ans paths; use the icon of LKL (i.e., it has following infos of all apps: id, name and path - and so icon)

\LiberKey\LiberKeyTools\LiberKeyMenu\data\categories.db.xml
- it lists all current categories and subcategories with icons
- use it to create to group your shortcut in folders as in LiberKey (i.e., it has the following infos of categories: id and icon)

\LiberKeyTools\LiberKeyMenu\data\Menu\default.xml
- it links infos of above files and give current translation texts
- use it to finish your work

Uh, i just came back to see my thread, and found your kind replies.
Thankyou a lot!
Anyway, some days ago I just built this small CMD script to make the dirty work:

Code: Tout sélectionner

@Echo Off
Title LKSC - LiberKey Shortcuts Creator

Set LKROOT=D:\LiberKey\Apps
Set LKSHORTCUTS="%PROGRAMDATA%\Microsoft\Windows\Start Menu\Programs\LiberKey Shortcuts"

Cls
Echo -------------------------------------------------------------------------------
Echo LIBERKEY SHORTCUTS CREATOR
Echo -------------------------------------------------------------------------------
Echo LiberKey Apps folder must be located here: %LKROOT%
Echo.
Echo Press any key to create all the shortcuts under this main folder:
Echo %LKSHORTCUTS%
Echo.
Echo Otherwise, close this window.
Echo -------------------------------------------------------------------------------
Pause >NUL

MkDir %LKSHORTCUTS%
For /R "%LKROOT%" %%G In (*LKL.exe) Do (
   shortcut.exe /F:%LKSHORTCUTS%\"%%~nG".lnk /A:C /T:%%G >NUL
   If Exist %LKSHORTCUTS%\"%%~nG".lnk (Echo SHORTCUT CREATED: %%~nG) Else (Echo --^> ERROR CREATING: %%~nG)
   )
Pause


You will need this SHORTCUT.EXE small utility placed inside C:\Windows\, or in the same directory as the CMD file, or inside any directory pointed from the PATH environment variable:
http://www.optimumx.com/downloads.html#Shortcut

Edit the two "Set SOMETHING" lines at the beginning of the script, and give it a try.
Hope you like it!

Sorry, you will need this SHORTCUT.EXE small utility placed inside C:\Windows\ or in the same directory as the CMD file:
http://www.optimumx.com/downloads.html#Shortcut

Hi,

On my PC (windows xp home edition) I had to make some small modifications on the script above in order to let it work.
Basically I have changed some quotation marks.
Here is the new script:

Code: Tout sélectionner

@Echo Off
Title LKSC - LiberKey Shortcuts Creator

Set LKROOT=D:\LiberKey\Apps
Set LKSHORTCUTS=%PROGRAMDATA%\Microsoft\Windows\Start Menu\Programs\LiberKey Shortcuts

Cls
Echo -------------------------------------------------------------------------------
Echo LIBERKEY SHORTCUTS CREATOR
Echo -------------------------------------------------------------------------------
Echo LiberKey Apps folder must be located here: %LKROOT%
Echo.
Echo Press any key to create all the shortcuts under this main folder:
Echo %LKSHORTCUTS%
Echo.
Echo Otherwise, close this window.
Echo -------------------------------------------------------------------------------
Pause >NUL

MkDir "%LKSHORTCUTS%"
For /R "%LKROOT%" %%G In (*LKL.exe) Do (
   shortcut.exe /F:"%LKSHORTCUTS%\%%~nG.lnk" /A:C /T:%%G >NUL
   If Exist "%LKSHORTCUTS%\%%~nG.lnk" (Echo SHORTCUT CREATED: %%~nG) Else (Echo --^> ERROR CREATING: %%~nG)
   )
Pause